home
***
CD-ROM
|
disk
|
FTP
|
other
***
search
/
United Public Domain Gold 2
/
United Public Domain Gold 2.iso
/
music_utilities
/
pt140.dms
/
pt140.adf
/
install
< prev
next >
Wrap
Text File
|
1994-04-30
|
29KB
|
1,104 lines
; This piece installs the Eagleplayer (TM) to your hard disk
; © 1993 DEFECT INC. All rights reserved.
;
; Written by Buggs/DFT
(set #EP_Version (cat "1.52")) ;Eagleplayer Version
(set #EP_Disk1 (cat "Eagleplayer.Disk.1:")) ;Name of first Disk
(set #EP_Disk2 (cat "Eagleplayer.Disk.2:")) ;Name of Second Disk
(set #Space (cat "1.4 ")) ;Megabytes needed for
;installation.
(set KickVersion (/ (getversion) 65536))
(debug "Kickversion:" Kickversion)
;=========================== English texts ==================================
(set Docfile ("Eagleplayer.Doc.Guide"))
(set #which-disk
(cat "In which drawer shall I install the Eagleplayer?\n"
"(no own directory will be created by the script)"
))
(Set #intro
(cat "\n\n This procedurce lets you install the full Eagleplayer Version "
#EP_Version
"including the needed libraries on your hard drive. Any previous "
"release already present will be replaced. For installing the full "
"package you need about "
#Space
"MBytes free space on your harddisk. \n"
"With the default installation settings the Eagleplayer needs much "
"more than 1MB of available memory. Please cunsult the manual how "
"to save memory e.g. by deleting not needed replayers or userprograms "
"or use the Batch functions (chapter 4.4 in the GUIDE file). "
))
(Set #WhatInstall
(cat "Which parts of the Eagleplayer Package do you want to install now ?"
))
(Set #WhatHelp
(cat "Here you are asked to choose between the different parts of the "
"Eagleplayer package you want to get. Simply to start the Eagleplayer "
"the Main Program and the needed libraries are enough. \n"
"To be able playing modules of all supported formats you have to install "
"the supplied replayers. \n"
"For the analyzing and some extended controlling features you may choose "
"to install the so called Userprograms. \n"
"The Documentation is recommended to read for learning to know and to "
"handle all the abilities of this package. READ IT BEFORE COMPLAINING "
"ABOUT SEVERAL PROBLEMS !! \n"
"The Noiseconverter is a little Utility to convert several Moduleformats "
"into the standard Protracker format or another supported one. It has "
"got much more abilities than any other Soundconverter program. \n\n"
@askoptions-help
))
(Set MainProgname
(cat "Eagleplayer Main Program"
))
(set Eagleplayersname
(cat "External Replayers"
))
(set Libsname
(cat "needed Libraries"
))
(set Userprogramsname
(cat "Userprograms (Analyzers, etc.)"
))
(set Documentationname
(cat "Documentations"
))
(set ArexxScriptsname
(cat "Arexx Example Scripts"
))
(set DeveloperKitname
(cat "Developer Examples & include Files"
))
(set Noiseconvertername
(cat "Noiseconverter"
))
(set #where-libs
(cat "Enter the Path where your LIBS: Directory is situated when you "
"boot from your Harddisk !"
))
(set #where-key
(cat "Enter the Path where your DEVS: Directory is situated when you "
"boot from your Harddisk !"
))
(set #where-rexx
(cat "Enter the Path where your REXX: Directory is situated when you "
"boot from your Harddisk !"
))
(set #where-envarc
(cat "Enter the Path where your ENVARC: Directory is situated when you "
"boot from your Harddisk !"
))
(set #where-locale
(cat "Enter the Path where your LOCALE: Directory is situated when you "
"boot from your Harddisk !"
))
(set #Betterabort
(cat "OK, you booted from the Eagleplayer Disk. That means that this install "
"script doesn`t know your system`s settings and default drawers. If "
"you (due to the fact that you selected \"novice user\") don`t know "
"what and where your \"DEVS:\",\"REXX:\" and \"LIBS:\" paths are on your "
"harddisk then you better select \"ABORT INSTALL\", reboot your machine "
"from your harddisk and then put the Eagleplayer Disk 1 into your drive "
"and start this install-script again. Then this script will find these "
"paths automatically !"
))
(set #Betterboot
(cat "OK, you booted from the Egleplayer Disk. That means you have to select "
"\"Libs:\",\"DEVS:\",\"REXX:\" and \"ENVARC:\" manually. If you don`t "
"want you better reboot from harddisk. "
))
(set #InstallReplays
(cat "Installing the external Replayers, please wait."
))
(set #which-user13
(cat "Which Kickstart 1.3 compatible Userprograms you wish to be installed ?"
))
(set #which-user20
(cat "Which Userprograms requiering OS 2.0 you wish to be installed ?"
))
(set #which-user30
(cat "Which Userprograms requiering OS 3.0 you wish to be installed ?"
))
(set #which-user-help
(cat "This procedure asks you for selecting the Userprograms"
" this program should install. Userprograms are the external modules"
" the Eagleplayer loads out of the external Players. These can be"
" Analyzers, Scopes or new Surfaces. Please notice that some"
" Userprograms may take a lot of memory, so if you only own 1 MB"
" of even less memory, choose only these you really like. (HIFI-System"
" e.g. takes about 100 kB memory when it`s loaded) The Userprograms"
" marked with a "R"- sign at the beginning are only available for the"
" registered users and won`t be loaded in the general version. So if"
" you are not registered you don`t need to install them. "
@Askoptions-help
))
(set #copyingdocs
(cat "Installing the Amigaguide® Documentation File"
))
(set #copyinglocale
(cat "Installing the Localisation File(s)"
))
(set #copydocs
(cat "Where to copy the Eagleplayer documentation ?"
))
(set #copydocshelp
(cat "Please confirm the Path you want to put these docs to."
))
(set #copyingexamples
(cat "Installing the Developer Example Files"
))
(set #copyexamples
(cat "Where to copy the Eagleplayer developer examples ?"
))
(set #copyexampleshelp
(cat "The Program asks you if you want to get the developer"
" examples, the Resource (TM) symbolfile and the Testplayer onto"
" your had disk. For users with no experiences in Assembler-coding"
" these files shouldn`t be useful at all (I think). "
))
(set #copyingarexx
(cat "Installing the Arexx Example Files"
))
(set #copybonus
(cat "Where to copy the Noiseconverter ?"
))
(set #copybonusshelp
(cat "The Program asks where you want to get the Noiseconverter onto "
"your hard disk. This program is a proggy to convert several "
"music formats to each other, like Perverter or ProWizard but "
"much more powerful"
))
(set #copymods
(cat "Where to copy the supplied Soundmodules ?"
))
(set #copymodshelp
(cat "Simply select whether you want the modules on your hard disk or"
"not and when yes, where you want them."
))
(set #copyprefs
(cat "Copying default preferences...."
))
(set #copykey
(cat "Copying your personal Keyfile to devs:"
))
(set #copyhelp
(cat "Copying your Helpfile"
))
(set #copyprefsok
(cat "Proceed"
))
(set #copyprefsno
(cat "Skip this part"
))
(set #copyincludes
(cat "Where to copy the Eagleplayer include files ?"
))
(set #copyincludeshelp
(cat "Only for developers, the Eagleplayer include file needed for"
" creating own Replayroutines or Userprograms (not documented yet)."
))
;=========================== Deutsche Texte =================================
(if (= @language "deutsch")
(
(set Docfile ("Eagleplayer.Dok.Guide"))
(set #which-disk
(cat "Wo soll der Eagleplayer installiert werden ? "
"(es wird kein eigenes Vezeichnis angelegt)"
))
(Set #intro
(cat "\n\n Dieser Vorgang ermöglicht es Ihnen, das komplette Eagleplayer-Paket "
#EP_Version
" samt den benötigten Bibliotheken auf Ihrer Harddisk zu installieren. "
" jede vorherige Version wird ersetzt. Zur Installation des kompletten "
" Paketes werden etwa "
#Space
"MBytes freier Platz auf der Festplatte benötigt. Mit den dabei "
"installierten Einstellungen wird erheblich mehr als 1 MB Arbeitsspeicher "
"beansprucht. Lesen Sie dafür in der Anleitung nach, wie Sie Speicher "
"sparen können. (Kapitel 4.4 \"Batch Dateien\") "
"Sie können auch nicht benötigte externe Abspieler oder Userprogramme "
"wieder löschen."
))
(Set #WhatInstall
(cat "Welche Teile des Eagleplayerpaketes möchten Sie jetzt installieren ?"
))
(Set #WhatHelp
(cat "Sie sollten nun auswählen, welche Teile des Eagleplayerpaketes Sie "
"haben wollen. Um den Eagleplayer starten zu können ist lediglich "
"das Hauptprogramm notwendig. (bei Bedarf die Libraries noch dazu) \n"
"Um Musikstücke aller unterstützter Formate abzuspielen müssen Sie "
"zwangsweise auch die externen Abspieler mit installieren.\n"
"Für die Analyzer und einige externe Kontrollfunktionen benötigen "
"Sie die sogenannten \"Userprogramme\".\n"
"Die Dokumentation zu installieren wird ihnen wärmstens ans Herz gelegt, "
"schließlich handelt es sich hier um ein Paket von weit über 1MB Umfang."
"AUßERDEM SOLLTEN SIE ERST IN DER ANLEITUNG NACHLESEN, BEVOR SIE SICH "
"BESCHWEREN.\n"
"Der Noiseconverter ist ein kleines Hilfsprogramm in der Art wie "
"\"Perverter\" und \"Prowizard\", nur erheblich umfangreicher. "
"Beispielsweise läßt sich mit diesem Programm die Gesamtspielzeit "
"der geladenen Module auf die Sekunde genau anzeigen.\n\n"
@askoptions-help
))
(Set MainProgname
(cat "Eagleplayer Hauptprogramm"
))
(set Eagleplayersname
(cat "Externe Abspieler"
))
(set Libsname
(cat "benutzte Libraries"
))
(set Userprogramsname
(cat "Userprogramme"
))
(set Documentationname
(cat "Dokumentation"
))
(set ArexxScriptsname
(cat "Arexx Beispieldateien"
))
(set DeveloperKitname
(cat "Entwicklerunterlagen"
))
(set Noiseconvertername
(cat "Noiseconverter"
))
(set #where-libs
(cat "Bitte geben Sie den Pfad an, wo sich das LIBS: Verzeichnis befindet, "
"wenn Sie von Festplatte booten !"
))
(set #where-key
(cat "Bitte geben Sie den Pfad an, wo sich das DEVS: Verzeichnis befindet, "
"wenn Sie von Festplatte booten !"
))
(set #where-rexx
(cat "Bitte geben Sie den Pfad an, wo sich das REXX: Verzeichnis befindet, "
"wenn Sie von Festplatte booten !"
))
(set #where-envarc
(cat "Bitte geben Sie den Pfad an, wo sich das ENVARC: Verzeichnis befindet, "
"wenn Sie von Festplatte booten !"
))
(set #where-locale
(cat "Bitte geben Sie den Pfad an, wo sich das LOCALE: Verzeichnis befindet, "
"wenn Sie von Festplatte booten !"
))
(set #Betterabort
(cat "OK, Sie haben von der Eagleplayer Disk 1 gebootet. Dies bedeutet, daß "
"die Installationsdatei allein nicht herausfinden kann, wo sich die "
"Systemverzeichnisse befinden, wenn Sie von Festplatte hochfahren. "
"Da Sie \"Anfänger\" als Installationsoption angegeben haben, würde "
"ich vorschlagen, daß Sie \"Abort Install\" anwählen, ihren Rechner "
"neustarten und dann erst die Eagleplayerdiskette einlegen, nachdem "
"der Rechner von Festplatte hochgefahren ist. Dies würde für Sie "
"als Anfänger erheblich einfacher werden."
))
(set #InstallReplays
(cat "Installiere die externen Abspieler, bitte warten ...."
))
(set #which-user13
(cat "Welche unter Kickstart 1.3 nutzbaren Userprogramme möchten Sie "
"installieren ?"
))
(set #which-user20
(cat "Welche Userprogramme, die OS 2.0 erfordern, möchten Sie installieren ?"
))
(set #which-user30
(cat "Welche Userprogramme, die OS 3.0 erfordern, möchten Sie installieren ?"
))
(set #which-user-help
(cat "Dieser Programmteil fragt Sie, welche Userprogramme Sie installieren"
" möchten. Userprogramme sind die externen Module, die außer den externen"
" Abspielroutinen beim Start des Programmes oder später geladen werden."
" Dieses können Spektrum Analyzer, Oszilliscopesimulatoren oder neue"
" Oberflächen sein. Bitte beachten Sie, daß einige Userprogramme eine"
" ganze Menge Speicher beanspruchen und somit sollten Sie bei nur 1 MB"
" oder gar weniger Hauptspeicher nur die auswählen, die Sie auch wirlich"
" oft nutzen. (so z.B. braucht "HIFI System" etwa 100 kByte) Diejenigen"
" Userprogramme, die mit einem "R" am Anfang gekennzeichnet sind, können"
" nur geladen werden, wenn Sie im Besitz einer registrierten Eagleplayer"
"version sind und Ihr Keyfile richtig installiert haben. "
@Askoptions-help
))
(set #copyingdocs
(cat "Installiere die Amigaguide® Dokumentationsdatei"
))
(set #copyinglocale
(cat "Installiere die Übersetzten Dateien"
))
(set #copydocs
(cat "Wohin soll ich die Eagleplayer Dokumentation kopieren ?"
))
(set #copydocshelp
(cat "Bitte bestätigen Sie den Verzeichnispfad, wohin ich die Anleitungen"
" hinzukopieren habe."
))
(set #copyingexamples
(cat "Installiere die Entwicklerbeispiele..."
))
(set #copyexamples
(cat "Wohin soll ich die Eagleplayer Entwicklerbeispiele kopieren ?"
))
(set #copyexampleshelp
(cat "Sie wurden gefragt ob Sie die Enfwickkerbeispiele, das Resource-"
"Symbolfile und den Testplayer installieren möchten. FÜr Anwender"
" ohne Assemblererfahrungen sind diese Dateien kaum relevant. "
))
(set #copyingarexx
(cat "Installiere die Arexx Beispieldateien"
))
(set #copybonus
(cat "Wohin soll ich den Noiseconverter kopieren ?"
))
(set #copybonusshelp
(cat "Nur die Frage, wo Sie den Noiseconverter, ein Tool zum umwandeln "
"diverser Soundtrackerformate hinkopieren wollen. Dieses Programm "
"ist ein Tool der Art wie der 'Perverter' oder 'Prowizard', nur "
"viel mächtiger."
))
(set #copymods
(cat "Wohin mit den mitgelieferten Musikstücken ?"
))
(set #copymodshelp
(cat "Wollen Sie sie nun, oder nicht ??"
))
(set #copyprefs
(cat "Kopiere die vordefinierten Einstellungen..."
))
(set #copyprefshelp
(cat "Ja wat nu ?"
))
(set #copykey
(cat "Kopiere Ihr persönliches Keyfile nach devs:"
))
(set #copyhelp
(cat "Kopiere Datei für Online-Hilfe"
))
(set #copyprefsok
(cat "Weiter"
))
(set #copyprefsno
(cat "Diesen Teil überspingen"
))
)
)
;======================= Prozeduren und Hilfsroutinen ======================
(procedure DepackFile
;Extract one file from an lha archive
; syntax:
; (set #Message ("Installing %s/%s..." Destdir Filename))
; (set ArchiveName ("%sEagleplayers.lha" #EP_Disk1))
; (set Destination (tackon target "Eagleplayers/"))
; (set FileName ("Actionamics"))
; (Depackfile)
(
(working #Message)
(set Error (run ("RAM:lha -q -Qp -N -wRAM: x %s \"%s\" \"%s\"" ArchiveName Destination FileName)))
(if (<> Error 0)
(message
("Cannot Depack %s from the archive %s to %s" FileName ArchiveName Destination
)
)
)
)
)
(procedure DepackFiles
;Extract all files from an lha archive
; syntax:
; (set #Message ("Installing Bla Bla"))
; (set ArchiveName ("%sEagleplayers.lha" #EP_Disk1))
; (set Destination (tackon target "Eagleplayers/"))
; (Depackfiles)
(
(debug "In Entpackroutine für ganze Dirs")
(working #Message)
(set Error (run ("RAM:lha -q -Qp -N -wRAM: x %s \"%s\"" ArchiveName Destination)))
(if (<> Error 0)
(message
("Cannot Depack from the archive %s to \n" ArchiveName
"%s" Destination
)
)
)
)
)
(procedure DepackUserprg
(
(if (IN maxfiles n)
(
(protect (tackon target (tackon "EP-Userprograms/" UPSFileName)) "+rwed")
(delete (tackon target (tackon "EP-Userprograms/" UPSFileName)))
(set #Message ("Installing EP-Userprograms/%s..." UPSFilename))
(set Destination (tackon target "EP-Userprograms/"))
(set FileName UPSFilename)
(depackfile)
)
)
)
)
;============================== Welcome the User ===========================
(set @app-name (cat "Eagleplayer" #EP_version))
(set APPNAME (cat "Eagleplayer" #EP_version))
;(welcome)
(set old_level @user-level)
(user 2)
(message #intro)
(user old_level)
;======================== Ask what he wants to install =======================
(set #InstallParts
(askoptions
(prompt #WhatInstall)
(help #WhatHelp)
(choices
("%s" MainProgname) ;Bit 0
("%s" Eagleplayersname) ;Bit 1
("%s" Userprogramsname) ;Bit 2
("%s" Libsname) ;Bit 3
("%s" Documentationname) ;Bit 4
("%s" ArexxScriptsname) ;Bit 5
("%s" DeveloperKitname) ;Bit 6
("%s" Noiseconvertername) ;Bit 7
)
)
)
;====== get target directory where the Eagleplayer is to be installed =====
(user 2)
(set target (askdir (prompt #which-disk)
(help @askdir-help)
(default "DH0:")
(disk)
)
)
(set @default-dest target)
(user old_level)
;=========== find out if we booted from Eagleplayer disk or not ==========
;----------- and ask for the libs,devs and rexx path if needed ----------
;did we boot from the Eagleplayer
(set Booted ;disk ?
(expandpath "sys:")
)
(if (<> #EP_Disk1 Booted)
;(if (= #EP_Disk1 Booted) ;für Testzwecke
( (set Libpath ('Libs:'))
(set Keypath ('Devs:'))
(set Rexxpath ('Rexx:'))
(set Envarcpath "Envarc:")
(set Localepath ('Locale:'))
(debug "Sys: ist nicht gleich EP-Disk !" Booted)
)
(
(set Keypath target)
(user 2)
(if (= old_level 0)
( (message (#Betterabort))
)
( (message (#Betterboot))
)
)
(if (IN #InstallParts 3)
(
(set Libpath
(askdir (prompt #where-libs)
(help @askdir-help)
(default "DH0:libs")
(disk)
)
)
)
)
(if (IN #InstallParts 5)
(
(set Rexxpath
(askdir (prompt #where-rexx)
(help @askdir-help)
(default "DH0:rexx")
(disk)
)
)
)
)
(if (AND (IN #InstallParts 7) (> KickVersion 37))
(
(set Localepath
(askdir (prompt #where-locale)
(help @askdir-help)
(default "DH0:locale")
(disk)
)
)
)
)
(if (IN #InstallParts 0)
(
(set Envarcpath
(askdir (prompt #where-envarc)
(help @askdir-help)
(default "DH0:prefs/env-archive")
(disk)
)
)
(set keypresent (exists (tackon #EP_Disk1 "devs/Eagleplayer.key"))
)
(if (= keypresent 1)
(
(set Keypath (askdir (prompt #where-key)
(help @askdir-help)
(default "DH0:devs")
(disk)
)
)
)
)
)
)
(debug "Alternative Pfade, da von Disk gebootet !" Booted)
(user old_level)
)
)
;=================== Ask for the Userprograms ============================
(if (AND (= @user-level 2) (IN #InstallParts 2))
(
(set user13
(askoptions (prompt #which-user13)
(help #which-user-help)
(choices
"R Analyze.small" ;1
"- Levelgraph" ;2
"R Levelgraph2" ;4
"R Levelmeter" ;8
"- Time" ;16
"- Noiseeagle") ;32
)
)
(set user20
(askoptions (prompt #which-user20)
(help #which-user-help)
(choices
"- Analyzer" ;1
"- DirList Viewer" ;2
"- HiFi" ;4
"- M.E.L.G.U" ;8
"- Moduleinfo" ;16
"- Messagewindow" ;32
"R Monoscope" ;64
"- Patternscroll" ;128
"- Public Screen Manager" ;256
"- Space-Scope" ;512
"R Stereoscope" ;1024
"- Quadrascope" ;2048
"R Voicemeter") ;4096
)
)
(set user30
(askoptions (prompt #which-user30)
(help #which-user-help)
(choices
"- Levelmeter AGA") ;1
)
)
)
(
(set keypresent (exists (tackon #EP_Disk1 "devs/Eagleplayer.key"))
)
(if (= keypresent 1)
(
;setze Maske für registrierte Version (alle UPS)
(set user13 63) ;<- muß 2^(Anzahl der UPS) -1 sein !!!
(if (> kickversion 36)
(set user20 8191) ;<- muß 2^(Anzahl der UPS) -1 sein !!
(set user20 0) ;für Kick 1.3
)
(if (> kickversion 38)
(set user30 1) ;<- muß 2^(Anzahl der UPS) -1 sein !!
(set user30 0) ;für Kick 1.3
)
)
(
;setze Maske für unregistrierte Version (nur unregistrierte UPS)
(set user13 50)
(if (> kickversion 36)
(set user20 3007)
(set user20 0)
)
(if (> kickversion 38)
(set user30 1)
(set user30 0)
)
)
)
)
)
(debug "Ausgewählte Userprogramme:" user13 user20)
;Disk 1 ============ Copy LHA to Ram: (to depack all archives) ==============
(copyfiles
(prompt "")
(help "")
(source (tackon #EP_Disk1 "C/lha"))
(dest "RAM:")
)
;Disk 1 ========== Copy the Eagleplayer to the desired directory =============
; ========== if Exist: =============
; beside of this: default prefs, keyfile and helpfile
(if (IN #InstallParts 0)
(
(copyfiles (source (tackon #EP_Disk1 "Eagleplayer"))
(dest target)
(infos)
(optional "force" "nofail")
)
(set keypresent (exists Envarcpath))
(debug "Envarc gefunden:" keypresent)
(if (= keypresent 2)
(
(copyfiles (optional "nofail")
(source (tackon #EP_Disk1 "prefs/env-archive"))
(dest Envarcpath)
(prompt #copyprefs)
(help "")
(confirm)
(all)
)
)
)
(set keypresent (exists (tackon #EP_Disk1 "devs/Eagleplayer.key"))
)
(if (= keypresent 1)
(
(copyfiles (optional "nofail")
(source (tackon #EP_Disk1 "devs/Eagleplayer.key"))
(dest keypath)
(prompt #copykey)
(help "Read the Docs")
(confirm)
)
)
)
(set keypresent (exists (tackon #EP_Disk1 "Eagleplayer.help"))
)
(if (= keypresent 1)
(
(copyfiles (optional "nofail")
(source (tackon #EP_Disk1 "Eagleplayer.help"))
(dest target)
(prompt #copyhelp)
(help "Read the Docs")
(confirm)
)
)
)
)
)
;Disk 1 ====================== copy Bonus Programs ====================
(if (IN #InstallParts 7)
(
(copyfiles (source (tackon #EP_Disk1 "Noiseconverter"))
(dest target)
(prompt #copybonus)
(help #copybonushelp)
(confirm)
(infos)
(optional "force")
)
(if (> KickVersion 37)
(
(copyfiles (source (tackon #EP_Disk1 "Locale"))
(dest localepath)
(prompt #copyinglocale)
(help "")
(confirm)
(ALL)
(optional "force" "nofail")
)
)
)
)
)
;Disk 1 ================= copy Libraries ===================================
(if (IN #InstallParts 3)
(
(copylib
(prompt "Copy XPKMaster.library")
(help @copylib-help)
(source (tackon #EP_Disk1 "LIBS/XPKMaster.library"))
(dest Libpath)
(confirm)
(optional "nofail")
)
(copyfiles
(prompt "Copy XPKNuke.library")
(help @copylib-help)
(source (tackon #EP_Disk1 "LIBS/Compressors/"))
(dest (tackon Libpath "Compressors"))
(confirm)
(optional "nofail")
(all)
)
(copylib
(prompt "Copy Powerpacker.library")
(help @copylib-help)
(source (tackon #EP_Disk1 "LIBS/Powerpacker.library"))
(dest Libpath)
(confirm)
(optional "nofail")
)
(copylib
(prompt "Copy LH.library")
(help @copylib-help)
(source (tackon #EP_Disk1 "LIBS/lh.library"))
(dest Libpath)
(confirm)
(optional "nofail")
)
(copylib
(prompt "Copy Req.library")
(help @copylib-help)
(source (tackon #EP_Disk1 "LIBS/req.library"))
(dest Libpath)
(confirm)
(optional "nofail")
)
(copylib
(prompt "Copy Reqtools.library")
(help @copylib-help)
(source (tackon #EP_Disk1 "LIBS/req.library"))
(dest Libpath)
(confirm)
(optional "nofail")
)
)
)
;Disk 2 ============== copy the external Players to be installed ========
(if (IN #InstallParts 1)
(
(makedir (tackon target "Eagleplayers")
(infos)
)
(set #Message #InstallReplays)
(set ArchiveName ("%sEagleplayers.lha" #EP_Disk2))
(set Destination (tackon target "Eagleplayers/"))
(Depackfiles)
)
)
;Disk 2======================== copy Docs ===================================
; Betriebssystem < 3.0 -> Install Amigaguide
(if (IN #InstallParts 4)
(
(set doctarget (askdir (prompt #copydocs)
(help #copydocshelp)
(default target)
(disk)
)
)
(if (< Kickversion 39)
(
(copylib
(prompt "Copy Amigaguide.library")
(help @copylib-help)
(source (tackon #EP_Disk1 "LIBS/Amigaguide.library"))
(dest Libpath)
(confirm)
)
(copyfiles (source (tackon #EP_Disk1 "utilities/Amigaguide"))
(dest doctarget)
(infos)
(confirm)
)
(copyfiles (source ("%sIcons/%s.info" #EP_Disk1 Docfile))
(dest doctarget)
)
)
)
(set #Message #copyingdocs)
(set ArchiveName ("%sDocs.lha" #EP_Disk2))
(set Destination "ram:")
(set FileName Docfile)
(Depackfile)
(if (> Kickversion 38)
(
(set #Message #copyingdocs)
(set ArchiveName ("%sDocs.lha" #EP_Disk2))
(set Destination "ram:")
(set FileName ("%s.info" Docfile))
(debug Filename)
(debug Archivename)
(Depackfile)
)
)
(set ramtest (expandpath doctarget))
(set ramtest2 (expandpath "ram:"))
(if (<> ramtest ramtest2)
(
(copyfiles (source (tackon "ram:" docfile))
(dest doctarget)
(infos)
)
(delete (tackon "ram:" docfile))
; (set yo (exists ("ram:%s.info" docfile)))
; (if (=yo 1)
; (delete ("ram:%s.info" docfile))
; )
)
)
)
)
;Disk 2 =============== copy the Userprograms ===========================
(if (IN #InstallParts 2)
(
(makedir (tackon target "EP-Userprograms")
(infos)
)
(if (<> user13 0)
(
(set n 0)
(set maxfiles user13)
(set ArchiveName ("%sUserprograms.lha" #EP_Disk2))
(while (set UPSFileName
(select n
"Analyze.small"
"Levelgraph"
"Levelgraph2"
"Levelmeter"
"Time"
"Noiseeagle"
""
)
)
(Depackuserprg)
(set n (+ n 1))
)
)
)
(if (<> user20 0)
(
(set n 0)
(set maxfiles user20)
(while (set UPSFileName
(select n
"Analyzer"
"DirListViewer"
"HiFi"
"M.E.L.G.U"
"Moduleinfo"
"Messagewindow"
"Monoscope"
"Patternscroll"
"PublicScreenmanager"
"Space-scope"
"Stereoscope"
"Quadrascope"
"Voicemeter"
""
)
)
(Depackuserprg)
(set n (+ n 1))
)
)
)
(if (<> user30 0)
(
(set n 0)
(set maxfiles user30)
(while (set UPSFileName
(select n
"LevelmeterAGA"
""
)
)
(Depackuserprg)
(set n (+ n 1))
)
)
)
)
)
;Disk 2 ===================== copy Examples ================================
(if (IN #InstallParts 6)
(
(set examplestarget (askdir (prompt #copyexamples)
(help #copyexampleshelp)
(default target)
(disk)
)
)
(set #Message #copyingexamples)
(set ArchiveName ("%sDeveloper.lha" #EP_Disk2))
(set Destination examplestarget)
(Depackfiles)
)
)
;Disk 2 ===================== copy Arexx-Scripts =======================
(if (IN #InstallParts 5)
(
(set #Message #copyingarexx)
(set ArchiveName ("%sArexxExamples.lha" #EP_Disk2))
(set Destination Rexxpath)
(Depackfiles)
)
)
;============= ready installing the Eagleplayer =======================
(delete "ram:lha")
(exit)